Planet
navi homePPSaboutscreenshotsdownloaddevelopmentforum

source: code/trunk/cmake/InstallConfig.cmake @ 8405

Last change on this file since 8405 was 8405, checked in by rgrieder, 10 years ago

Added MSVC option to install the *.pdb debug symbols files as well.

  • Property svn:eol-style set to native
File size: 4.3 KB
Line 
1 #
2 #             ORXONOX - the hottest 3D action shooter ever to exist
3 #                             > www.orxonox.net <
4 #
5 #        This program is free software; you can redistribute it and/or
6 #         modify it under the terms of the GNU General Public License
7 #        as published by the Free Software Foundation; either version 2
8 #            of the License, or (at your option) any later version.
9 #
10 #       This program is distributed in the hope that it will be useful,
11 #        but WITHOUT ANY WARRANTY; without even the implied warranty of
12 #        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 #                 GNU General Public License for more details.
14 #
15 #   You should have received a copy of the GNU General Public License along
16 #      with this program; if not, write to the Free Software Foundation,
17 #     Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
18 #
19 #
20 #  Author:
21 #    Reto Grieder
22 #  Description:
23 #    Configures the installation (paths, rpaths, options)
24 #
25
26IF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT) # Variable provided by CMake
27  IF("$ENV{ORXONOX_DEV}" OR TARDIS)
28    SET(_install_prefix_changed 1)
29    SET(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/install CACHE PATH
30        "Install path prefix, prepended onto install directories." FORCE)
31  ENDIF()
32ENDIF()
33
34SET(_info_text "Puts all installed files in subfolders of the install prefix path. That root folder can then be moved, copied and renamed as you wish. The executable will not write to folders like ~/.orxonox or \"Applictation Data\"")
35IF(UNIX AND NOT _install_prefix_changed)
36  OPTION(INSTALL_COPYABLE "${_info_text}" FALSE)
37ELSE()
38  OPTION(INSTALL_COPYABLE "${_info_text}" TRUE)
39ENDIF()
40
41IF(MSVC)
42  # Allow developers to install the debug symbols as well (safes the copying)
43  OPTION(INSTALL_PDB_FILES "Also installs the debug symbol files" FALSE)
44ENDIF()
45
46# Default relative installation paths
47SET(RUNTIME_INSTALL_DIRECTORY ${DEFAULT_RUNTIME_PATH})
48SET(LIBRARY_INSTALL_DIRECTORY ${DEFAULT_LIBRARY_PATH})
49SET(ARCHIVE_INSTALL_DIRECTORY ${DEFAULT_ARCHIVE_PATH})
50SET(MODULE_INSTALL_DIRECTORY  ${DEFAULT_MODULE_PATH})
51SET(DOC_INSTALL_DIRECTORY     ${DEFAULT_DOC_PATH})
52SET(DATA_INSTALL_DIRECTORY    ${DEFAULT_DATA_PATH})
53SET(CONFIG_INSTALL_DIRECTORY  ${DEFAULT_CONFIG_PATH})
54SET(LOG_INSTALL_DIRECTORY     ${DEFAULT_LOG_PATH})
55
56IF(NOT INSTALL_COPYABLE)
57  IF(LINUX)
58    # Using absolute paths
59    SET(RUNTIME_INSTALL_DIRECTORY games)
60    SET(LIBRARY_INSTALL_DIRECTORY lib/games/orxonox)
61    SET(ARCHIVE_INSTALL_DIRECTORY lib/games/orxonox/static)
62    SET(MODULE_INSTALL_DIRECTORY  lib/games/orxonox/modules)
63    SET(DOC_INSTALL_DIRECTORY     share/doc/orxonox)
64    SET(DATA_INSTALL_DIRECTORY    share/games/orxonox)
65  ELSEIF(WIN32)
66    # Leave on default (installs to only one location anyway)
67  ELSEIF(APPLE)
68    # TODO: Figure out what's the best way to install the application
69  ENDIF()
70
71  # Leave empty because it is user and therefore runtime dependent
72  SET(CONFIG_INSTALL_DIRECTORY)
73  SET(LOG_INSTALL_DIRECTORY)
74ENDIF()
75
76################## Unix rpath ###################
77
78# Use, i.e. don't skip the full RPATH for the build tree
79SET(CMAKE_SKIP_BUILD_RPATH  FALSE)
80
81# When building, don't use the install RPATH already
82# (but later on when installing)
83SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
84
85# The RPATH to be used when installing
86IF(INSTALL_COPYABLE)
87  # Get relative paths from run to lib and from module to lib directory.
88  FILE(RELATIVE_PATH _runtime_rpath "/${RUNTIME_INSTALL_DIRECTORY}" "/${LIBRARY_INSTALL_DIRECTORY}")
89  FILE(RELATIVE_PATH _module_rpath  "/${MODULE_INSTALL_DIRECTORY}" "/${LIBRARY_INSTALL_DIRECTORY}")
90  # $ORIGIN (with $ escaped) refers to the actual location of the library
91  # The UNIX loader recognises this special variable
92  SET(RUNTIME_RPATH "\$ORIGIN/${_runtime_rpath}")
93  SET(LIBRARY_RPATH "\$ORIGIN")
94  SET(MODULE_RPATH  "\$ORIGIN:\$ORIGIN/${_module_rpath}")
95ELSE()
96  SET(RUNTIME_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBRARY_INSTALL_DIRECTORY}")
97  SET(LIBRARY_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBRARY_INSTALL_DIRECTORY}")
98  SET(MODULE_RPATH  "${LIBRARY_RPATH}:${CMAKE_INSTALL_PREFIX}/${MODULE_INSTALL_DIRECTORY}")
99ENDIF()
100
101# Add the automatically determined parts of the RPATH
102# which point to directories outside the build tree to the install RPATH
103SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
Note: See TracBrowser for help on using the repository browser.