| 1 | # |
|---|
| 2 | # ORXONOX - the hottest 3D action shooter ever to exist |
|---|
| 3 | # > www.orxonox.net < |
|---|
| 4 | # |
|---|
| 5 | # This program is free software; you can redistribute it and/or |
|---|
| 6 | # modify it under the terms of the GNU General Public License |
|---|
| 7 | # as published by the Free Software Foundation; either version 2 |
|---|
| 8 | # of the License, or (at your option) any later version. |
|---|
| 9 | # |
|---|
| 10 | # This program is distributed in the hope that it will be useful, |
|---|
| 11 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 12 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
|---|
| 13 | # GNU General Public License for more details. |
|---|
| 14 | # |
|---|
| 15 | # You should have received a copy of the GNU General Public License along |
|---|
| 16 | # with this program; if not, write to the Free Software Foundation, |
|---|
| 17 | # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA. |
|---|
| 18 | # |
|---|
| 19 | # |
|---|
| 20 | # Author: |
|---|
| 21 | # Reto Grieder |
|---|
| 22 | # Description: |
|---|
| 23 | # Adds a library or an executable like ADD_LIBRARY/ADD_EXECUTABLE, but |
|---|
| 24 | # accepts a lot more input information. Simply supply the keywords |
|---|
| 25 | # described below in any order you wish. |
|---|
| 26 | # The output is then stored in "_arg_ARGNAME" where ARGNAME is the the |
|---|
| 27 | # name of the switch or list. |
|---|
| 28 | # |
|---|
| 29 | # Switches: (when given --> TRUE, FALSE otherwise) |
|---|
| 30 | # FIND_HEADER_FILES: Searches the current directory for all header files |
|---|
| 31 | # and adds them to the target. |
|---|
| 32 | # EXCLUDE_FROM_ALL: Inherited from ADD_LIBRARY/ADD_EXECUTABLE |
|---|
| 33 | # ORXONOX_EXTERNAL: Specify this for third party libraries |
|---|
| 34 | # NO_DLL_INTERFACE: Link statically with MSVC |
|---|
| 35 | # NO_SOURCE_GROUPS: Don't create msvc source groups |
|---|
| 36 | # STATIC/SHARED: Inherited from ADD_LIBRARY |
|---|
| 37 | # MODULE: For dynamic module libraries |
|---|
| 38 | # WIN32: Inherited from ADD_EXECUTABLE |
|---|
| 39 | # PCH_NO_DEFAULT: Do not make precompiled header files default if |
|---|
| 40 | # specified with PCH_FILE |
|---|
| 41 | # NO_INSTALL: Do not install the target at all |
|---|
| 42 | # NO_VERSION: Prevents adding any version to a target |
|---|
| 43 | # |
|---|
| 44 | # Lists: |
|---|
| 45 | # LINK_LIBRARIES: Redirects to TARGET_LINK_LIBRARIES |
|---|
| 46 | # VERSION: Set version to the binary |
|---|
| 47 | # SOURCE_FILES: Source files for the target |
|---|
| 48 | # DEFINE_SYMBOL: Sets the DEFINE_SYMBOL target property |
|---|
| 49 | # Usage: DEFINE_SYMBOL static "symbol" shared "symbol2" |
|---|
| 50 | # (or shared "symbol2" static "symbol") |
|---|
| 51 | # TOLUA_FILES: Files with tolua interface |
|---|
| 52 | # PCH_FILE: Precompiled header file |
|---|
| 53 | # PCH_EXCLUDE: Source files to be excluded from PCH support |
|---|
| 54 | # OUTPUT_NAME: If you want a different name than the target name |
|---|
| 55 | # Note: |
|---|
| 56 | # This function also installs the target! |
|---|
| 57 | # Prerequisistes: |
|---|
| 58 | # ORXONOX_DEFAULT_LINK, ORXONOX_CONFIG_FILES |
|---|
| 59 | # Parameters: |
|---|
| 60 | # _target_name, ARGN for the macro arguments |
|---|
| 61 | # |
|---|
| 62 | |
|---|
| 63 | INCLUDE(CMakeDependentOption) |
|---|
| 64 | INCLUDE(CapitaliseName) |
|---|
| 65 | INCLUDE(GenerateToluaBindings) |
|---|
| 66 | INCLUDE(ParseMacroArguments) |
|---|
| 67 | INCLUDE(SourceFileUtilities) |
|---|
| 68 | IF(PCH_COMPILER_SUPPORT) |
|---|
| 69 | INCLUDE(PrecompiledHeaderFiles) |
|---|
| 70 | ENDIF() |
|---|
| 71 | |
|---|
| 72 | MACRO(ORXONOX_ADD_LIBRARY _target_name) |
|---|
| 73 | TU_ADD_TARGET(${_target_name} LIBRARY "STATIC;SHARED" ${ARGN}) |
|---|
| 74 | ENDMACRO(ORXONOX_ADD_LIBRARY) |
|---|
| 75 | |
|---|
| 76 | MACRO(ORXONOX_ADD_EXECUTABLE _target_name) |
|---|
| 77 | TU_ADD_TARGET(${_target_name} EXECUTABLE "WIN32" ${ARGN}) |
|---|
| 78 | ENDMACRO(ORXONOX_ADD_EXECUTABLE) |
|---|
| 79 | |
|---|
| 80 | |
|---|
| 81 | MACRO(TU_ADD_TARGET _target_name _target_type _additional_switches) |
|---|
| 82 | CAPITALISE_NAME(${_target_name} _target_name_capitalised) |
|---|
| 83 | STRING(TOUPPER "${_target_name}" _target_name_upper) |
|---|
| 84 | |
|---|
| 85 | # Specify all possible options (either switch or with add. arguments) |
|---|
| 86 | SET(_switches FIND_HEADER_FILES EXCLUDE_FROM_ALL ORXONOX_EXTERNAL |
|---|
| 87 | NO_DLL_INTERFACE NO_SOURCE_GROUPS ${_additional_switches} |
|---|
| 88 | PCH_NO_DEFAULT NO_INSTALL MODULE NO_VERSION) |
|---|
| 89 | SET(_list_names LINK_LIBRARIES VERSION SOURCE_FILES DEFINE_SYMBOL |
|---|
| 90 | TOLUA_FILES PCH_FILE PCH_EXCLUDE OUTPUT_NAME) |
|---|
| 91 | PARSE_MACRO_ARGUMENTS("${_switches}" "${_list_names}" ${ARGN}) |
|---|
| 92 | |
|---|
| 93 | |
|---|
| 94 | # Workaround: Source file properties get lost when leaving a subdirectory |
|---|
| 95 | # Therefore an "H" after a file means we have to set it as HEADER_FILE_ONLY |
|---|
| 96 | FOREACH(_file ${_arg_SOURCE_FILES}) |
|---|
| 97 | IF(_file STREQUAL "H") |
|---|
| 98 | SET_SOURCE_FILES_PROPERTIES(${_last_file} PROPERTIES HEADER_FILE_ONLY TRUE) |
|---|
| 99 | ELSE() |
|---|
| 100 | SET(_last_file ${_file}) |
|---|
| 101 | LIST(APPEND _${_target_name}_source_files ${_file}) |
|---|
| 102 | ENDIF() |
|---|
| 103 | ENDFOREACH(_file) |
|---|
| 104 | |
|---|
| 105 | # Assemble all header files of the library |
|---|
| 106 | IF(_arg_FIND_HEADER_FILES) |
|---|
| 107 | GET_ALL_HEADER_FILES(_${_target_name}_header_files) |
|---|
| 108 | ENDIF() |
|---|
| 109 | |
|---|
| 110 | # Remove potential duplicates |
|---|
| 111 | SET(_${_target_name}_files ${_${_target_name}_header_files} ${_${_target_name}_source_files}) |
|---|
| 112 | LIST(REMOVE_DUPLICATES _${_target_name}_files) |
|---|
| 113 | |
|---|
| 114 | # Generate the source groups |
|---|
| 115 | IF(NOT _arg_NO_SOURCE_GROUPS) |
|---|
| 116 | GENERATE_SOURCE_GROUPS(${_${_target_name}_files}) |
|---|
| 117 | |
|---|
| 118 | IF(NOT _arg_ORXONOX_EXTERNAL) |
|---|
| 119 | # Move the prereqs.h file to the config section |
|---|
| 120 | IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${_target_name_capitalised}Prereqs.h) |
|---|
| 121 | SOURCE_GROUP("Config" FILES ${_target_name_capitalised}Prereqs.h) |
|---|
| 122 | ENDIF() |
|---|
| 123 | # Add the config files in a special source group |
|---|
| 124 | LIST(APPEND _${_target_name}_files ${ORXONOX_CONFIG_FILES}) |
|---|
| 125 | SOURCE_GROUP("Config" FILES ${ORXONOX_CONFIG_FILES}) |
|---|
| 126 | ENDIF() |
|---|
| 127 | ENDIF(NOT _arg_NO_SOURCE_GROUPS) |
|---|
| 128 | |
|---|
| 129 | # TOLUA_FILES |
|---|
| 130 | IF(_arg_TOLUA_FILES) |
|---|
| 131 | GENERATE_TOLUA_BINDINGS(${_target_name_capitalised} _${_target_name}_files |
|---|
| 132 | INPUTFILES ${_arg_TOLUA_FILES}) |
|---|
| 133 | ENDIF() |
|---|
| 134 | |
|---|
| 135 | # First part (pre target) of precompiled header files |
|---|
| 136 | IF(PCH_COMPILER_SUPPORT AND _arg_PCH_FILE) |
|---|
| 137 | # Provide convenient option to control PCH |
|---|
| 138 | IF(_arg_PCH_NO_DEFAULT) |
|---|
| 139 | SET(PCH_DEFAULT FALSE) |
|---|
| 140 | ELSE() |
|---|
| 141 | SET(PCH_DEFAULT TRUE) |
|---|
| 142 | ENDIF() |
|---|
| 143 | CMAKE_DEPENDENT_OPTION(PCH_ENABLE_${_target_name_upper} |
|---|
| 144 | "Enable using precompiled header files for library ${_target_name}." ${PCH_DEFAULT} PCH_ENABLE OFF) |
|---|
| 145 | |
|---|
| 146 | IF(PCH_ENABLE_${_target_name_upper}) |
|---|
| 147 | PRECOMPILED_HEADER_FILES_PRE_TARGET(${_target_name} ${_arg_PCH_FILE} _${_target_name}_files EXCLUDE ${_arg_PCH_EXCLUDE}) |
|---|
| 148 | ENDIF() |
|---|
| 149 | ENDIF() |
|---|
| 150 | |
|---|
| 151 | # Certain libraries don't have dllexport/dllimport and can't be linked shared with msvc |
|---|
| 152 | IF(MSVC AND _arg_NO_DLL_INTERFACE) |
|---|
| 153 | SET(_arg_SHARED) |
|---|
| 154 | SET(_arg_STATIC STATIC) |
|---|
| 155 | ENDIF() |
|---|
| 156 | |
|---|
| 157 | # No warnings needed from third party libraries |
|---|
| 158 | IF(_arg_ORXONOX_EXTERNAL) |
|---|
| 159 | REMOVE_COMPILER_FLAGS("-W3 -W4" MSVC) |
|---|
| 160 | ADD_COMPILER_FLAGS("-w") |
|---|
| 161 | ENDIF() |
|---|
| 162 | |
|---|
| 163 | # Set default linking if required |
|---|
| 164 | IF(NOT _arg_SHARED AND NOT _arg_STATIC) |
|---|
| 165 | IF("${ORXONOX_DEFAULT_LINK}" STREQUAL "STATIC") |
|---|
| 166 | SET(_arg_STATIC STATIC) |
|---|
| 167 | ELSEIF("${ORXONOX_DEFAULT_LINK}" STREQUAL "SHARED") |
|---|
| 168 | SET(_arg_SHARED SHARED) |
|---|
| 169 | ENDIF() |
|---|
| 170 | ENDIF() |
|---|
| 171 | |
|---|
| 172 | # MODULE A |
|---|
| 173 | # Always create shared libraries |
|---|
| 174 | IF(_arg_MODULE) |
|---|
| 175 | SET(_arg_SHARED SHARED) |
|---|
| 176 | SET(_arg_STATIC) |
|---|
| 177 | ENDIF() |
|---|
| 178 | |
|---|
| 179 | # Don't compile header files |
|---|
| 180 | FOREACH(_file ${_${_target_name}_files}) |
|---|
| 181 | IF(NOT _file MATCHES "\\.(c|cc|cpp)") |
|---|
| 182 | SET_SOURCE_FILES_PROPERTIES(${_file} PROPERTIES HEADER_FILE_ONLY TRUE) |
|---|
| 183 | ENDIF() |
|---|
| 184 | ENDFOREACH(_file) |
|---|
| 185 | |
|---|
| 186 | |
|---|
| 187 | |
|---|
| 188 | # Add the library/executable |
|---|
| 189 | IF("${_target_type}" STREQUAL "LIBRARY") |
|---|
| 190 | ADD_LIBRARY(${_target_name} ${_arg_STATIC} ${_arg_SHARED} |
|---|
| 191 | ${_arg_EXCLUDE_FROM_ALL} ${_${_target_name}_files}) |
|---|
| 192 | ELSE() |
|---|
| 193 | ADD_EXECUTABLE(${_target_name} ${_arg_WIN32} ${_arg_EXCLUDE_FROM_ALL} |
|---|
| 194 | ${_${_target_name}_files}) |
|---|
| 195 | ENDIF() |
|---|
| 196 | |
|---|
| 197 | |
|---|
| 198 | |
|---|
| 199 | # Change library prefix to "lib" |
|---|
| 200 | IF(MSVC AND ${_target_type} STREQUAL "LIBRARY") |
|---|
| 201 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES |
|---|
| 202 | PREFIX "lib" |
|---|
| 203 | ) |
|---|
| 204 | ENDIF() |
|---|
| 205 | |
|---|
| 206 | # MSVC hack to exclude external library sources from the intellisense database |
|---|
| 207 | # (IntelliSense stops working when adding "-Zm1000" as compile flag. "/Zm1000" |
|---|
| 208 | # would not work because of the slash) |
|---|
| 209 | IF(_arg_ORXONOX_EXTERNAL AND MSVC) |
|---|
| 210 | GET_TARGET_PROPERTY(_compile_flags ${_target_name} COMPILE_FLAGS) |
|---|
| 211 | IF(NOT _compile_flags) |
|---|
| 212 | SET(_compile_flags) |
|---|
| 213 | ENDIF() |
|---|
| 214 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES COMPILE_FLAGS "${_compile_flags} -Zm1000") |
|---|
| 215 | ENDIF() |
|---|
| 216 | |
|---|
| 217 | # MODULE B |
|---|
| 218 | IF (_arg_MODULE) |
|---|
| 219 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES |
|---|
| 220 | RUNTIME_OUTPUT_DIRECTORY ${CMAKE_MODULE_OUTPUT_DIRECTORY} # Windows |
|---|
| 221 | LIBRARY_OUTPUT_DIRECTORY ${CMAKE_MODULE_OUTPUT_DIRECTORY} # Unix |
|---|
| 222 | ) |
|---|
| 223 | ADD_MODULE(${_target_name}) |
|---|
| 224 | ENDIF() |
|---|
| 225 | |
|---|
| 226 | # LINK_LIBRARIES |
|---|
| 227 | IF(_arg_LINK_LIBRARIES) |
|---|
| 228 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBRARIES}) |
|---|
| 229 | ENDIF() |
|---|
| 230 | |
|---|
| 231 | # DEFINE_SYMBOL |
|---|
| 232 | IF(_arg_DEFINE_SYMBOL OR NOT _arg_ORXONOX_EXTERNAL) |
|---|
| 233 | IF(_arg_DEFINE_SYMBOL) |
|---|
| 234 | # Format is: static "static_symbol" shared "shared_symbol" |
|---|
| 235 | # but the order doesn't matter |
|---|
| 236 | LIST(LENGTH _arg_DEFINE_SYMBOL _define_symbol_length) |
|---|
| 237 | IF (_define_symbol_length LESS 2) |
|---|
| 238 | MESSAGE(FATAL_ERROR "Number of expected arguments for DEFINE_SYMBOL is at least 2: static \"STATIC_SYMBOL\" shared \"SHARED_SYMBOL\"") |
|---|
| 239 | ENDIF() |
|---|
| 240 | STRING(TOLOWER "${_arg_STATIC}${_arg_SHARED}" _static_shared_lower) |
|---|
| 241 | LIST(FIND _arg_DEFINE_SYMBOL ${_static_shared_lower} _symbol_definition_index) |
|---|
| 242 | MATH(EXPR _symbol_definition_index "${_symbol_definition_index} + 1") |
|---|
| 243 | IF(_symbol_definition_index LESS _define_symbol_length) |
|---|
| 244 | LIST(GET _arg_DEFINE_SYMBOL ${_symbol_definition_index} _symbol_definition) |
|---|
| 245 | ENDIF() |
|---|
| 246 | ELSE() |
|---|
| 247 | # Automatically add the macro definitions for our own libraries |
|---|
| 248 | SET(_symbol_definition "${_target_name_upper}_${_arg_STATIC}${_arg_SHARED}_BUILD") |
|---|
| 249 | ENDIF() |
|---|
| 250 | |
|---|
| 251 | # Use the DEFINE_SYMBOL property for shared builds (not used by CMake for static builds), |
|---|
| 252 | # but if we only use COMPILE_FLAGS, CMake will define a symbol anyway. |
|---|
| 253 | IF(_arg_SHARED) |
|---|
| 254 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES DEFINE_SYMBOL ${_symbol_definition}) |
|---|
| 255 | ELSE() |
|---|
| 256 | GET_TARGET_PROPERTY(_compile_flags ${_target_name} COMPILE_FLAGS) |
|---|
| 257 | IF(NOT _compile_flags) |
|---|
| 258 | SET(_compile_flags) |
|---|
| 259 | ENDIF() |
|---|
| 260 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES COMPILE_FLAGS "${_compile_flags} -D${_symbol_definition}") |
|---|
| 261 | ENDIF() |
|---|
| 262 | ENDIF() |
|---|
| 263 | |
|---|
| 264 | # VERSION |
|---|
| 265 | IF(_arg_VERSION) |
|---|
| 266 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES VERSION ${_arg_VERSION}) |
|---|
| 267 | ELSEIF(NOT _arg_ORXONOX_EXTERNAL AND NOT _arg_NO_VERSION AND NOT ${_target_type} STREQUAL "EXECUTABLE") |
|---|
| 268 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES VERSION ${ORXONOX_VERSION}) |
|---|
| 269 | ENDIF() |
|---|
| 270 | |
|---|
| 271 | # OUTPUT_NAME |
|---|
| 272 | IF(_arg_OUTPUT_NAME) |
|---|
| 273 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES OUTPUT_NAME ${_arg_OUTPUT_NAME}) |
|---|
| 274 | ENDIF() |
|---|
| 275 | |
|---|
| 276 | # Second part of precompiled header files |
|---|
| 277 | IF(PCH_COMPILER_SUPPORT AND PCH_ENABLE_${_target_name_upper} AND _arg_PCH_FILE) |
|---|
| 278 | PRECOMPILED_HEADER_FILES_POST_TARGET(${_target_name} ${_arg_PCH_FILE}) |
|---|
| 279 | ENDIF() |
|---|
| 280 | |
|---|
| 281 | IF((${_target_type} STREQUAL "EXECUTABLE" OR NOT _arg_STATIC) AND NOT _arg_NO_INSTALL) |
|---|
| 282 | IF(_arg_MODULE) |
|---|
| 283 | INSTALL(TARGETS ${_target_name} |
|---|
| 284 | RUNTIME DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 285 | LIBRARY DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 286 | ) |
|---|
| 287 | ELSE() |
|---|
| 288 | INSTALL(TARGETS ${_target_name} |
|---|
| 289 | RUNTIME DESTINATION ${RUNTIME_INSTALL_DIRECTORY} |
|---|
| 290 | LIBRARY DESTINATION ${LIBRARY_INSTALL_DIRECTORY} |
|---|
| 291 | ) |
|---|
| 292 | ENDIF() |
|---|
| 293 | ENDIF() |
|---|
| 294 | |
|---|
| 295 | ENDMACRO(TU_ADD_TARGET) |
|---|
| 296 | |
|---|
| 297 | |
|---|
| 298 | # Creates a helper file with name <name_of_the_library>${ORXONOX_MODULE_EXTENSION} |
|---|
| 299 | # This helps finding dynamically loadable modules at runtime |
|---|
| 300 | |
|---|
| 301 | FUNCTION(ADD_MODULE _target) |
|---|
| 302 | # We use the properties to get the name because the librarys name may differ from |
|---|
| 303 | # the target name (for example orxonox <-> liborxonox) |
|---|
| 304 | |
|---|
| 305 | GET_TARGET_PROPERTY(_target_loc ${_target} LOCATION) |
|---|
| 306 | GET_FILENAME_COMPONENT(_target_name ${_target_loc} NAME_WE) |
|---|
| 307 | |
|---|
| 308 | IF(CMAKE_CONFIGURATION_TYPES) |
|---|
| 309 | FOREACH(_config ${CMAKE_CONFIGURATION_TYPES}) |
|---|
| 310 | SET(_module_filename ${CMAKE_MODULE_OUTPUT_DIRECTORY}/${_config}/${_target_name}${ORXONOX_MODULE_EXTENSION}) |
|---|
| 311 | |
|---|
| 312 | FILE(WRITE ${_module_filename}) |
|---|
| 313 | |
|---|
| 314 | INSTALL( |
|---|
| 315 | FILES ${_module_filename} |
|---|
| 316 | DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 317 | CONFIGURATIONS ${_config} |
|---|
| 318 | ) |
|---|
| 319 | ENDFOREACH() |
|---|
| 320 | ELSE() |
|---|
| 321 | SET(_module_filename ${CMAKE_MODULE_OUTPUT_DIRECTORY}/${_target_name}${ORXONOX_MODULE_EXTENSION}) |
|---|
| 322 | |
|---|
| 323 | FILE(WRITE ${_module_filename}) |
|---|
| 324 | |
|---|
| 325 | INSTALL( |
|---|
| 326 | FILES ${_module_filename} |
|---|
| 327 | DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 328 | ) |
|---|
| 329 | ENDIF() |
|---|
| 330 | ENDFUNCTION(ADD_MODULE) |
|---|
