Planet
navi homePPSaboutscreenshotsdownloaddevelopmentforum

source: code/branches/ipv6/cmake/LibraryConfig.cmake @ 7329

Last change on this file since 7329 was 7329, checked in by adrfried, 14 years ago

compile with own libenet

  • Property svn:eol-style set to native
File size: 8.0 KB
Line 
1 #
2 #             ORXONOX - the hottest 3D action shooter ever to exist
3 #                             > www.orxonox.net <
4 #
5 #        This program is free software; you can redistribute it and/or
6 #         modify it under the terms of the GNU General Public License
7 #        as published by the Free Software Foundation; either version 2
8 #            of the License, or (at your option) any later version.
9 #
10 #       This program is distributed in the hope that it will be useful,
11 #        but WITHOUT ANY WARRANTY; without even the implied warranty of
12 #        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 #                 GNU General Public License for more details.
14 #
15 #   You should have received a copy of the GNU General Public License along
16 #      with this program; if not, write to the Free Software Foundation,
17 #     Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
18 #
19 #
20 #  Author:
21 #    Reto Grieder
22 #  Description:
23 #    Configures the external libraries. Whenever possible, the find scripts
24 #    from the CMake module path are used, but that required some adjustments
25 #    for certain libraries (Boost, OpenAL, TCL)
26 #
27
28INCLUDE(CompareVersionStrings)
29INCLUDE(FindPackageHandleStandardArgs)
30
31# Prevent CMake from finding libraries in the installation folder on Windows.
32# There might already be an installation from another compiler
33IF(WIN32)
34  LIST(REMOVE_ITEM CMAKE_SYSTEM_PREFIX_PATH  "${CMAKE_INSTALL_PREFIX}")
35  LIST(REMOVE_ITEM CMAKE_SYSTEM_LIBRARY_PATH "${CMAKE_INSTALL_PREFIX}/bin")
36ENDIF()
37
38############## Platform Scripts #################
39
40# On Windows using a package causes way less problems
41SET(_option_msg "Set this to true to use precompiled dependecy archives")
42IF(WIN32)
43  OPTION(DEPENDENCY_PACKAGE_ENABLE "${_option_msg}" ON)
44ELSE(WIN32)
45  OPTION(DEPENDENCY_PACKAGE_ENABLE "${_option_msg}" FALSE)
46ENDIF(WIN32)
47
48# Scripts for specific library and CMake config
49INCLUDE(LibraryConfigTardis)
50INCLUDE(LibraryConfigApple)
51
52IF(DEPENDENCY_PACKAGE_ENABLE)
53  GET_FILENAME_COMPONENT(_dep_dir_1 ${CMAKE_SOURCE_DIR}/../dependencies ABSOLUTE)
54  GET_FILENAME_COMPONENT(_dep_dir_2 ${CMAKE_SOURCE_DIR}/../lib_dist ABSOLUTE)
55  IF(MINGW)
56    SET(_compiler_prefix mingw)
57  ELSEIF(MSVC80)
58    SET(_compiler_prefix msvc8)
59  ELSEIF(MSVC90)
60    SET(_compiler_prefix msvc9)
61  ENDIF()
62  FIND_PATH(DEPENDENCY_PACKAGE_DIR
63    NAMES version.txt
64    PATHS
65      ${CMAKE_SOURCE_DIR}/dependencies
66      ${_dep_dir_1}
67      ${_dep_dir_2}
68    PATH_SUFFIXES ${_compiler_prefix} ${_compiler_prefix}/dependencies
69    NO_CMAKE_PATH NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
70  )
71  IF(NOT DEPENDENCY_PACKAGE_DIR)
72    MESSAGE(STATUS "Warning: Could not find dependency directory."
73                   "Disable LIBRARY_USE_PACKAGE if you have none intalled.")
74  ELSE()
75    INCLUDE(PackageConfigMinGW)
76    INCLUDE(PackageConfigMSVC)
77    INCLUDE(PackageConfig) # For both msvc and mingw
78  ENDIF()
79ENDIF(DEPENDENCY_PACKAGE_ENABLE)
80
81# User script
82SET(LIBRARY_CONFIG_USER_SCRIPT "" CACHE FILEPATH
83    "Specify a CMake script if you wish to write your own library path config.
84     See LibraryConfigTardis.cmake for an example.")
85IF(LIBRARY_CONFIG_USER_SCRIPT)
86  IF(EXISTS ${CMAKE_MODULE_PATH}/${LIBRARY_CONFIG_USER_SCRIPT})
87    INCLUDE(${CMAKE_MODULE_PATH}/${LIBRARY_CONFIG_USER_SCRIPT})
88  ENDIF()
89ENDIF(LIBRARY_CONFIG_USER_SCRIPT)
90
91
92############### Library finding #################
93# Performs the search and sets the variables    #
94
95FIND_PACKAGE(OGRE  1.4       REQUIRED)
96#FIND_PACKAGE(ENet  1.1       REQUIRED)
97FIND_PACKAGE(Ogg             REQUIRED)
98FIND_PACKAGE(Vorbis          REQUIRED)
99FIND_PACKAGE(ALUT            REQUIRED)
100FIND_PACKAGE(ZLIB            REQUIRED)
101IF(POCO_REQUIRED)
102  FIND_PACKAGE(POCO          REQUIRED)
103ENDIF()
104IF(WIN32)
105  FIND_PACKAGE(DirectX       REQUIRED)
106ENDIF()
107
108##### CEGUI #####
109# We make use of the CEGUI script module called CEGUILua.
110# However there is a small issue with that: We use Tolua, a C++ binding
111# generator ourselves. And we also have to use our bindings in the same
112# lua state is CEGUILua's. Unfortunately this implies that both lua runtime
113# version are equal or else you get segmentation faults.
114# In order to match the Lua versions we decided to ship CEGUILua in our
115# repository, mainly because there is no way to determine which version of
116# Lua CEGUILua was linked against (you'd have to specify yourself) and secondly
117# because we can then choose the Lua version. Future plans might involve only
118# accepting Lua 5.1.
119
120# Insert all internally supported CEGUILua versions here
121SET(CEGUILUA_INTERNAL_SUPPORT 0.5.0 0.6.0 0.6.1 0.6.2)
122OPTION(CEGUILUA_USE_EXTERNAL_LIBRARY "Force the use of external CEGUILua library" OFF)
123FIND_PACKAGE(CEGUI 0.5 REQUIRED)
124
125##### Lua #####
126IF(CEGUILUA_USE_EXTERNAL_LIBRARY)
127  COMPARE_VERSION_STRINGS(${CEGUI_VERSION} "0.6" _version_comparison)
128  IF(version_comparison LESS 0)
129    SET(LUA_VERSION_REQUEST 5.0)
130  ELSE()
131    SET(LUA_VERSION_REQUEST 5.1)
132  ENDIF()
133ELSE()
134  SET(LUA_VERSION_REQUEST 5)
135ENDIF()
136FIND_PACKAGE(Lua ${LUA_VERSION_REQUEST} EXACT REQUIRED)
137
138##### OpenAL #####
139FIND_PACKAGE(OpenAL REQUIRED)
140# Also use parent include dir (without AL/) for ALUT
141IF(OPENAL_INCLUDE_DIR MATCHES "/AL$")
142  GET_FILENAME_COMPONENT(ALT_OPENAL_INCLUDE_DIR ${OPENAL_INCLUDE_DIR} PATH)
143ENDIF()
144SET(OPENAL_INCLUDE_DIRS ${OPENAL_INCLUDE_DIR} ${ALT_OPENAL_INCLUDE_DIR})
145# Notfiy user
146FIND_PACKAGE_HANDLE_STANDARD_ARGS(OpenAL DEFAULT_MSG OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
147# Hide variables created by the script
148MARK_AS_ADVANCED(OPENAL_INCLUDE_DIR OPENAL_LIBRARY)
149
150##### Tcl #####
151# We only require Tcl, so avoid confusing user about other Tcl stuff by
152# applying a little workaround
153SET(Tclsh_FIND_QUIETLY TRUE)
154FIND_PACKAGE(TCL QUIET)
155# Display messages separately
156SET(TCL_FIND_QUIETLY FALSE)
157FIND_PACKAGE_HANDLE_STANDARD_ARGS(TCL DEFAULT_MSG TCL_LIBRARY TCL_INCLUDE_PATH)
158
159##### Boost #####
160# Expand the next statement if newer boost versions than 1.36.1 are released
161SET(Boost_ADDITIONAL_VERSIONS 1.37 1.37.0 1.38 1.38.0 1.39 1.39.0 1.40 1.40.0
162                              1.41 1.41.0 1.42 1.42.0 1.43 1.43.0 1.44 1.44.0)
163IF( NOT TARDIS )
164  FIND_PACKAGE(Boost 1.35 REQUIRED thread filesystem system date_time)
165ENDIF()
166# No auto linking, so this option is useless anyway
167MARK_AS_ADVANCED(Boost_LIB_DIAGNOSTIC_DEFINITIONS)
168
169
170####### Static/Dynamic linking options ##########
171
172# On Windows dynamically linked libraries need some special treatment
173# You may want to edit these settings if you provide your own libraries
174# Note: Default option in the libraries vary, but our default option is dynamic
175IF(WIN32)
176  OPTION(LINK_BOOST_DYNAMIC "Link Boost dynamically on Windows" TRUE)
177  OPTION(LINK_CEGUI_DYNAMIC "Link CEGUI dynamicylly on Windows" TRUE)
178  OPTION(LINK_ENET_DYNAMIC  "Link ENet dynamically on Windows" TRUE)
179  OPTION(LINK_OGRE_DYNAMIC  "Link OGRE dynamically on Windows" TRUE)
180  OPTION(LINK_TCL_DYNAMIC   "Link TCL dynamically on Windows" TRUE)
181  OPTION(LINK_ZLIB_DYNAMIC  "Link ZLib dynamically on Windows" TRUE)
182  COMPARE_VERSION_STRINGS("${LUA_VERSION}" "5.1" _version_comparison)
183  IF(_version_comparison LESS 0)
184    OPTION(LINK_LUA_DYNAMIC "Link Lua dynamically on Windows" FALSE)
185  ELSE(_version_comparison LESS 0)
186    OPTION(LINK_LUA_DYNAMIC "Link Lua dynamically on Windows" TRUE)
187  ENDIF(_version_comparison LESS 0)
188
189  IF(DEPENDENCY_PACKAGE_ENABLE)
190    MARK_AS_ADVANCED(
191      LINK_BOOST_DYNAMIC LINK_CEGUI_DYNAMIC LINK_ENET_DYNAMIC
192      LINK_OGRE_DYNAMIC  LINK_TCL_DYNAMIC   LINK_ZLIB_DYNAMIC
193      LINK_LUA_DYNAMIC
194    )
195  ENDIF()
196ENDIF(WIN32)
197
198
199################# OGRE Plugins ##################
200
201# More plugins: Plugin_BSPSceneManager, Plugin_OctreeSceneManager
202SET(OGRE_PLUGINS_INT Plugin_ParticleFX)
203IF(WIN32)
204  # CG program manager is probably DirectX related (not available under unix)
205  LIST(APPEND OGRE_PLUGINS_INT Plugin_CgProgramManager)
206ENDIF(WIN32)
207SET(OGRE_PLUGINS ${OGRE_PLUGINS_INT} CACHE STRING
208   "Specify which OGRE plugins to load. Existance check is performed.")
209
210# Check the plugins and determine the plugin folder
211# You can give a hint by setting the environment variable ENV{OGRE_PLUGIN_DIR}
212INCLUDE(CheckOGREPlugins)
213CHECK_OGRE_PLUGINS(${OGRE_PLUGINS})
214
Note: See TracBrowser for help on using the repository browser.