Planet
navi homePPSaboutscreenshotsdownloaddevelopmentforum

source: code/trunk/src/CMakeLists.txt @ 8079

Last change on this file since 8079 was 8079, checked in by landauf, 13 years ago

merged usability branch back to trunk

incomplete summary of the changes in this branch:

  • enhanced keyboard navigation in GUIs
  • implemented new graphics menu and changeable window size at runtime
  • added developer mode
  • HUD shows if game is paused, game pauses if ingame menu is opened
  • removed a few obsolete commands and hid some that are more for internal use
  • numpad works in console and gui
  • faster loading of level info
  • enhanced usage of compositors (Shader class)
  • improved camera handling, configurable FOV and aspect ratio
  • Property svn:eol-style set to native
File size: 6.4 KB
Line 
1 #
2 #             ORXONOX - the hottest 3D action shooter ever to exist
3 #                             > www.orxonox.net <
4 #
5 #        This program is free software; you can redistribute it and/or
6 #         modify it under the terms of the GNU General Public License
7 #        as published by the Free Software Foundation; either version 2
8 #            of the License, or (at your option) any later version.
9 #
10 #       This program is distributed in the hope that it will be useful,
11 #        but WITHOUT ANY WARRANTY; without even the implied warranty of
12 #        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 #                 GNU General Public License for more details.
14 #
15 #   You should have received a copy of the GNU General Public License along
16 #      with this program; if not, write to the Free Software Foundation,
17 #     Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
18 #
19 #
20 #  Author:
21 #    Reto Grieder
22 #  Description:
23 #    Configures the compilers and sets build options.
24 #
25
26# Required macros and functions
27INCLUDE(FlagUtilities)
28INCLUDE(TargetUtilities)
29
30# Configure the two headers and set some options
31INCLUDE(OrxonoxConfig.cmake)
32
33####### Library Behaviour (dependencies) ########
34
35# Disable auto linking completely for Boost and POCO
36ADD_COMPILER_FLAGS("-DBOOST_ALL_NO_LIB")
37ADD_COMPILER_FLAGS("-DPOCO_NO_AUTOMATIC_LIBS")
38
39# If no defines are specified, these libs get linked statically
40ADD_COMPILER_FLAGS("-DBOOST_ALL_DYN_LINK" WIN32 LINK_BOOST_DYNAMIC)
41#ADD_COMPILER_FLAGS("-DENET_DLL"           WIN32 LINK_ENET_DYNAMIC)
42ADD_COMPILER_FLAGS("-DLUA_BUILD_AS_DLL"   WIN32 LINK_LUA_DYNAMIC)
43ADD_COMPILER_FLAGS("-DZLIB_DLL"           WIN32 LINK_ZLIB_DYNAMIC)
44# If no defines are specified, these libs get linked dynamically
45ADD_COMPILER_FLAGS("-DCEGUI_STATIC"       WIN32 NOT LINK_CEGUI_DYNAMIC)
46ADD_COMPILER_FLAGS("-DOGRE_STATIC_LIB"    WIN32 NOT LINK_OGRE_DYNAMIC)
47ADD_COMPILER_FLAGS("-DSTATIC_BUILD"       WIN32 NOT LINK_TCL_DYNAMIC)
48
49######### Library Behaviour (external) ##########
50
51# Use TinyXML++
52ADD_COMPILER_FLAGS("-DTIXML_USE_TICPP")
53
54# Default linking for externals is SHARED
55SET(ORXONOX_EXTERNAL_LINK_MODE SHARED CACHE STRING "Link mode for external libraries that we build ourselves. Note: on Windows, some libraries cannot be linked shared.")
56
57IF(ORXONOX_EXTERNAL_LINK_MODE STREQUAL "SHARED")
58  SET(_external_shared_link TRUE)
59ELSE()
60  SET(_external_shared_link FALSE)
61ENDIF()
62# If no defines are specified, these libs get linked dynamically
63ADD_COMPILER_FLAGS("-DCEGUILUA_STATIC"             WIN32 NOT _external_shared_link)
64ADD_COMPILER_FLAGS("-DENET_DLL"                    WIN32     _external_shared_link)
65ADD_COMPILER_FLAGS("-DOGRE_GUIRENDERER_STATIC_LIB" WIN32 NOT _external_shared_link)
66ADD_COMPILER_FLAGS("-DOIS_STATIC_LIB"              WIN32 NOT _external_shared_link)
67ADD_COMPILER_FLAGS("-DTOLUA_STATIC_BUILD"          WIN32 NOT _external_shared_link)
68
69############## Include Directories ##############
70
71# Set the search paths for include files
72INCLUDE_DIRECTORIES(
73  # External
74  ${OGRE_INCLUDE_DIR}
75  ${CEGUI_INCLUDE_DIR}
76  #${ENET_INCLUDE_DIR}
77  ${Boost_INCLUDE_DIRS}
78  ${POCO_INCLUDE_DIR}
79  ${OPENAL_INCLUDE_DIRS}
80  ${ALUT_INCLUDE_DIR}
81  ${VORBIS_INCLUDE_DIR}
82  ${OGG_INCLUDE_DIR}
83  ${LUA_INCLUDE_DIR}
84  ${TCL_INCLUDE_PATH}
85  ${DIRECTX_INCLUDE_DIR}
86  ${ZLIB_INCLUDE_DIR}
87
88  # All includes in "externals" should be prefixed with the path
89  # relative to "external" to avoid conflicts
90  ${CMAKE_CURRENT_SOURCE_DIR}/external
91  # Include directories needed even if only included by Orxonox
92  ${CMAKE_CURRENT_SOURCE_DIR}/external/bullet
93  ${CMAKE_CURRENT_SOURCE_DIR}/external/ois
94
95  # OrxonoxConfig.h
96  ${CMAKE_CURRENT_BINARY_DIR}
97)
98
99IF(CEGUILUA_USE_INTERNAL_LIBRARY)
100  INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/external/ceguilua/ceguilua-${CEGUI_VERSION})
101ENDIF()
102
103IF (DBGHELP_FOUND)
104  INCLUDE_DIRECTORIES(${DBGHELP_INCLUDE_DIR})
105ENDIF()
106
107################### Tolua Bind ##################
108
109# Create directory because the tolua application doesn't work otherwise
110IF(NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
111  FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
112ENDIF()
113
114INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
115
116################ Sub Directories ################
117
118ADD_SUBDIRECTORY(external)
119ADD_SUBDIRECTORY(libraries)
120ADD_SUBDIRECTORY(orxonox)
121SET(ORXONOX_MODULES CACHE INTERNAL "")
122ADD_SUBDIRECTORY(modules)
123
124################## Executable ###################
125
126INCLUDE_DIRECTORIES(
127  ${CMAKE_CURRENT_SOURCE_DIR}/libraries
128  ${CMAKE_CURRENT_SOURCE_DIR}/orxonox
129)
130
131# Translate argument
132IF(ORXONOX_USE_WINMAIN)
133  SET(ORXONOX_WIN32 WIN32)
134ENDIF()
135
136ORXONOX_ADD_EXECUTABLE(orxonox-main
137  # When defined as WIN32 this removes the console window on Windows
138  ${ORXONOX_WIN32}
139  LINK_LIBRARIES
140    orxonox
141  SOURCE_FILES
142    Orxonox.cc
143  OUTPUT_NAME orxonox
144)
145# Main executable should depend on all modules
146ADD_DEPENDENCIES(orxonox-main ${ORXONOX_MODULES})
147
148# Get name to configure the run scripts
149GET_TARGET_PROPERTY(_exec_loc orxonox-main LOCATION)
150GET_FILENAME_COMPONENT(_exec_name ${_exec_loc} NAME)
151SET(ORXONOX_EXECUTABLE_NAME ${_exec_name} CACHE INTERNAL "")
152
153
154# When using Visual Studio we want to use the output directory as working
155# directory and we also want to specify where the external dlls
156# (lua, ogre, etc.) are. The problem hereby is that these information cannot
157# be specified in CMake because they are not stored in the actual project file.
158# This workaround will create a configured *.vcproj.user file that holds the
159# right values. When starting the solution for the first time,
160# these get written to the *vcproj.yourPCname.yourname.user
161IF(MSVC)
162  IF(CMAKE_CL_64)
163    SET(MSVC_PLATFORM "x64")
164  ELSE()
165    SET(MSVC_PLATFORM "Win32")
166  ENDIF()
167  STRING(REGEX REPLACE "^Visual Studio ([0-9][0-9]?) .*$" "\\1"
168         VISUAL_STUDIO_VERSION_SIMPLE "${CMAKE_GENERATOR}")
169  CONFIGURE_FILE("${CMAKE_CURRENT_SOURCE_DIR}/orxonox-main.vcproj.user.in" "${CMAKE_CURRENT_BINARY_DIR}/orxonox-main.vcproj.user")
170ENDIF(MSVC)
171
172#################### Doxygen ####################
173
174# Prepare include paths for Doxygen. This is necessary to display
175# the correct path to use when including a file, e.g.
176# core/XMLPort.h instead of src/core/XMLPort.h
177
178INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/modules)
179GET_DIRECTORY_PROPERTY(_temp INCLUDE_DIRECTORIES)
180# Replace ';' by spaces
181STRING(REPLACE ";" " " _temp "${_temp}")
182SET(DOXYGEN_INCLUDE_DIRECTORIES "${_temp}" PARENT_SCOPE)
Note: See TracBrowser for help on using the repository browser.