Planet
navi homePPSaboutscreenshotsdownloaddevelopmentforum

source: code/branches/ipv6/src/CMakeLists.txt @ 7329

Last change on this file since 7329 was 7329, checked in by adrfried, 14 years ago

compile with own libenet

  • Property svn:eol-style set to native
File size: 5.7 KB
Line 
1 #
2 #             ORXONOX - the hottest 3D action shooter ever to exist
3 #                             > www.orxonox.net <
4 #
5 #        This program is free software; you can redistribute it and/or
6 #         modify it under the terms of the GNU General Public License
7 #        as published by the Free Software Foundation; either version 2
8 #            of the License, or (at your option) any later version.
9 #
10 #       This program is distributed in the hope that it will be useful,
11 #        but WITHOUT ANY WARRANTY; without even the implied warranty of
12 #        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 #                 GNU General Public License for more details.
14 #
15 #   You should have received a copy of the GNU General Public License along
16 #      with this program; if not, write to the Free Software Foundation,
17 #     Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
18 #
19 #
20 #  Author:
21 #    Reto Grieder
22 #  Description:
23 #    Configures the compilers and sets build options.
24 #
25
26# Required macros and functions
27INCLUDE(FlagUtilities)
28INCLUDE(TargetUtilities)
29
30# Configure the two headers and set some options
31INCLUDE(OrxonoxConfig.cmake)
32
33####### Library Behaviour (dependencies) ########
34
35# Disable Boost auto linking completely
36ADD_COMPILER_FLAGS("-DBOOST_ALL_NO_LIB")
37
38# If no defines are specified, these libs get linked statically
39ADD_COMPILER_FLAGS("-DBOOST_ALL_DYN_LINK" WIN32 LINK_BOOST_DYNAMIC)
40ADD_COMPILER_FLAGS("-DENET_DLL"           WIN32 LINK_ENET_DYNAMIC)
41ADD_COMPILER_FLAGS("-DLUA_BUILD_AS_DLL"   WIN32 LINK_LUA_DYNAMIC)
42ADD_COMPILER_FLAGS("-DZLIB_DLL"           WIN32 LINK_ZLIB_DYNAMIC)
43# If no defines are specified, these libs get linked dynamically
44ADD_COMPILER_FLAGS("-DCEGUI_STATIC"       WIN32 NOT LINK_CEGUI_DYNAMIC)
45ADD_COMPILER_FLAGS("-DOGRE_STATIC_LIB"    WIN32 NOT LINK_OGRE_DYNAMIC)
46ADD_COMPILER_FLAGS("-DSTATIC_BUILD"       WIN32 NOT LINK_TCL_DYNAMIC)
47
48######### Library Behaviour (external) ##########
49
50# Use TinyXML++
51ADD_COMPILER_FLAGS("-DTIXML_USE_TICPP")
52
53# Default linking for externals is SHARED
54SET(ORXONOX_EXTERNAL_LINK_MODE SHARED CACHE STRING "Link mode for external libraries that we build ourselves. Note: on Windows, some libraries cannot be linked shared.")
55
56IF(ORXONOX_EXTERNAL_LINK_MODE STREQUAL "SHARED")
57  SET(_external_shared_link TRUE)
58ELSE()
59  SET(_external_shared_link FALSE)
60ENDIF()
61# If no defines are specified, these libs get linked dynamically
62ADD_COMPILER_FLAGS("-DCEGUILUA_STATIC"             WIN32 NOT _external_shared_link)
63ADD_COMPILER_FLAGS("-DOGRE_GUIRENDERER_STATIC_LIB" WIN32 NOT _external_shared_link)
64ADD_COMPILER_FLAGS("-DOIS_STATIC_LIB"              WIN32 NOT _external_shared_link)
65ADD_COMPILER_FLAGS("-DTOLUA_STATIC_BUILD"          WIN32 NOT _external_shared_link)
66
67############## Include Directories ##############
68
69# Set the search paths for include files
70INCLUDE_DIRECTORIES(
71  # External
72  ${OGRE_INCLUDE_DIR}
73  ${CEGUI_INCLUDE_DIR}
74  #${ENET_INCLUDE_DIR}
75  ${CMAKE_CURRENT_SOURCE_DIR}/external/enet/include
76  ${Boost_INCLUDE_DIRS}
77  ${POCO_INCLUDE_DIR}
78  ${OPENAL_INCLUDE_DIRS}
79  ${ALUT_INCLUDE_DIR}
80  ${VORBIS_INCLUDE_DIR}
81  ${OGG_INCLUDE_DIR}
82  ${LUA_INCLUDE_DIR}
83  ${TCL_INCLUDE_PATH}
84  ${DIRECTX_INCLUDE_DIR}
85  ${ZLIB_INCLUDE_DIR}
86  ${VLD_INCLUDE_DIR}
87
88  # All includes in "externals" should be prefixed with the path
89  # relative to "external" to avoid conflicts
90  ${CMAKE_CURRENT_SOURCE_DIR}/external
91  # Include directories needed even if only included by Orxonox
92  ${CMAKE_CURRENT_SOURCE_DIR}/external/bullet
93  ${CMAKE_CURRENT_SOURCE_DIR}/external/ois
94
95  # OrxonoxConfig.h
96  ${CMAKE_CURRENT_BINARY_DIR}
97)
98
99IF(CEGUILUA_USE_INTERNAL_LIBRARY)
100  INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/external/ceguilua/ceguilua-${CEGUI_VERSION})
101ENDIF()
102
103################### Tolua Bind ##################
104
105# Create directory because the tolua application doesn't work otherwise
106IF(NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
107  FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
108ENDIF()
109
110INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/toluabind/${CMAKE_CFG_INTDIR})
111
112################ Sub Directories ################
113
114ADD_SUBDIRECTORY(external)
115ADD_SUBDIRECTORY(libraries)
116ADD_SUBDIRECTORY(orxonox)
117ADD_SUBDIRECTORY(modules)
118
119################ Executable ################
120
121INCLUDE_DIRECTORIES(
122  ${CMAKE_CURRENT_SOURCE_DIR}/libraries
123  ${CMAKE_CURRENT_SOURCE_DIR}/orxonox
124)
125
126# Translate argument
127IF(ORXONOX_USE_WINMAIN)
128  SET(ORXONOX_WIN32 WIN32)
129ENDIF()
130
131ORXONOX_ADD_EXECUTABLE(orxonox-main
132  # When defined as WIN32 this removes the console window on Windows
133  ${ORXONOX_WIN32}
134  LINK_LIBRARIES
135    orxonox
136  SOURCE_FILES
137    Orxonox.cc
138  OUTPUT_NAME orxonox
139)
140
141# Get name to configure the run scripts
142GET_TARGET_PROPERTY(_exec_loc orxonox-main LOCATION)
143GET_FILENAME_COMPONENT(_exec_name ${_exec_loc} NAME)
144SET(ORXONOX_EXECUTABLE_NAME ${_exec_name} CACHE INTERNAL "")
145
146
147# When using Visual Studio we want to use the output directory as working
148# directory and we also want to specify where the external dlls
149# (lua, ogre, etc.) are. The problem hereby is that these information cannot
150# be specified in CMake because they are not stored in the actual project file.
151# This workaround will create a configured *.vcproj.user file that holds the
152# right values. When starting the solution for the first time,
153# these get written to the *vcproj.yourPCname.yourname.user
154IF(MSVC)
155  IF(CMAKE_CL_64)
156    SET(MSVC_PLATFORM "x64")
157  ELSE()
158    SET(MSVC_PLATFORM "Win32")
159  ENDIF()
160  STRING(REGEX REPLACE "^Visual Studio ([0-9][0-9]?) .*$" "\\1"
161         VISUAL_STUDIO_VERSION_SIMPLE "${CMAKE_GENERATOR}")
162  CONFIGURE_FILE("${CMAKE_CURRENT_SOURCE_DIR}/orxonox-main.vcproj.user.in" "${CMAKE_CURRENT_BINARY_DIR}/orxonox-main.vcproj.user")
163ENDIF(MSVC)
Note: See TracBrowser for help on using the repository browser.